|
|
|||||||
| Php, Asp, Flash, Java, Html Php, asp, flash, java, html ve tüm web azılım dilleri hakkında bilgi paylaşımı yapabileceğiniz bölüm. |
| Tags: veritabanindan access bilgileri |
 |
|
|
Seçenekler |
01-20-2008
|
#1 |
|
Se®ve® Administ®ato®
  |
Veritabanından (Access) Bilgileri Sayfaya Dökmenin En Yalın ve Kurallı Örneği
Konu : Veritabanından Bilgileri Sayfaya Dökmek
Seviye : Basit Kaynak Dosyalar : [ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] bu dosyaları C:\Inetpub\wwwroot dizini içinde ders adında bir klasör oluşturun ve içerisine koyun. Bundan sonra yazdığım kodlarıda buraya koyarsınız.   kayit_oku.asp Kod:
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>Veritabanından kayıt okumak</title>
<**** **********="Content-Type" content="text/html; charset=iso-8859-9">
</head>
<body>
<table border="1" cellpadding="0" cellspacing="0" width="100%">
<%
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
dim objRs
set objRs = Server.CreateObject("ADODB.Recordset")
objRs.CursorType = 0
objRs.CursorLocation = 2
objRs.LockType = 1
dim strSql
strSql = "SELECT * FROM tblUye"
objRs.Open strSql, objConn, , , &H0001
if objRs.EOF then
%>
<tr>
<td>Veritabanı boş</td>
</tr>
<%
else
do while Not objRs.EOF
%>
<tr>
<td><% = objRs("UYE_ID") %></td>
<td><% = objRs("UYE_AD") %></td>
<td><% = objRs("UYE_SOYAD") %></td>
<td><% = objRs("UYE_MAIL") %></td>
<td><% = objRs("UYE_SEHIR") %></td>
<td><% = objRs("UYE_MESAJ") %></td>
</tr>
<%
objRs.MoveNext()
loop
end if
objRs.Close
set objRs = Nothing
objConn.Close
set objConn = Nothing
%>
</table>
</body>
</html>
kısaca açıklayacak olursak; strConn isimli bir değişken tanımladık ve bu değişkene veritabanı bağlantı cümlesini atadık. Başına str eki koyduk ki bu değişkenin bir string olduğunu bize her zaman hatırlatsın... Kod:
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
objConn isimli bir değişken tanımladık ve bu değişkene veritabanı bağlantımızı sağlayacak olan Connection nesnesini atadık. Başına obj eki koyduk ki bu değişkenin bir Server Object (Sunucu Nesnesi) olduğunu bize her zaman hatırlatsın... Veritabanına bağlantı sağladık... Kod:
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
objRs isimli bir değişken tanımladık ve bu değişkene Recordset kayıtseti (kayıt dizisi) nesnesini atadık. Başına obj eki koyduk ki bu değişkenin bir Server Object (Sunucu Nesnesi) olduğunu bize her zaman hatırlatsın... Kod:
dim objRs
set objRs = Server.CreateObject("ADODB.Recordset")
kayıtsetinin CursorLocation değerini 2 parametresi verdik. kayıtsetinin LockType değerini 1 parametresi verdik. Kod:
objRs.CursorType = 0 objRs.CursorLocation = 2 objRs.LockType = 1 Kayıtsetinde onlarca farklı opsiyon ve bu opsiyonların birer nümerik karşılığı vardır. Normalde bu nümerik değerler yazılıdır. Nümerik ifadeleri akılda tutmak zor olduğu için bu nümerik ifadelerin karşılığını veren adovbs.inc kullanılır "1" yazmak yerine hatırlanması daha kolay olan "adOpenKeyset" yazabiliriz. Kayıtsetini açarken kullanabileceğimiz değerler aşağıdadır. <% '---- CursorTypeEnum Values ---- Const adOpenForwardOnly = 0 <=== Biz bunu kullandık Const adOpenKeyset = 1 Const adOpenDynamic = 2 Const adOpenStatic = 3 '---- CursorLocationEnum Values ---- Const adUseServer = 2 <=== Biz bunu kullandık Const adUseClient = 3 '---- LockTypeEnum Values ---- Const adLockReadOnly = 1 <=== Biz bunu kullandık Const adLockPessimistic = 2 Const adLockOptimistic = 3 Const adLockBatchOptimistic = 4 '---- EditModeEnum Values ---- Const adEditNone = &H0000 Const adEditInProgress = &H0001 <=== Biz bunu kullandık Const adEditAdd = &H0002 Const adEditDelete = &H0004 %> '---- CursorTypeEnum Values ---- Recordset içindeki hareketi kontrol eden bir özelliktir. Varsayılan olarak Forward-only kullanılır. Dört değişik tipten biri seçilebilir.
Forward-only Cursor (adOpenForwardOnly ya da 0) Forward only : (Sadece ilerle) Varsayılan kürsördür. Static Cursor'e benzer fakat kayıtlar arasında sadece ileriye doğru harekete izin verir. Yeni kayıt ekleyemeyiz ve yapılan değişiklikler kayıtsetini yeniden açıncaya kadar göremeyiz. Bu kürsörü listeleme işlemlerinde kullanarak performans artışı sağlayabiliriz. Keyset Cursor (adOpenKeyset ya da 1) Kayıtseti içindeki her tütlü harekete izin verir. Diğer kullanıcıların eklediği kayıtların görünmesini engeller. Diğer kullanıcıların sildiği kayıtlara erişilmez. Diğer kullanıcıların kayıtlar üzerinde yaptığı veri değişiklikleri anında yansıtılır. Dynamic Cursor (adOpenDynamic ya da 2) Dynamic : (Dinamik) Diğer kullanıcılar tarafından yapılan eklemelerin, değişikliklerin ve silmelerin anında görülmesini sağlar ve kayıtseti üzerindeyapılacak tüm hareketlere izin verir. Static Cursor (adOpenStatic ya da 3) Static : (Duragan) Belli verilerin bulunması ya da raporların üretilmesi için kullanılacak kayıtsetinin değişmeyen bir kopyasını oluşturur. Veri üzerinde her türlü harekete izin verir. Diğer kullanıcılar tarafından yapılan değişiklikler kayıtsetine yansıtılmaz. '---- LockTypeEnum Values ---- Kayıtsetinin kilitlenmesi için kullanılır. Dört farklı değer alabilir. adLockReadOnly ya da 1 Veriler sadece okunur şekildedir, değiştirilemez. adLockPessimistic ya da 2 Üzerinde işlem yapılan veriler satır bazında kilitlenir. Başka kullanıcıların erişimi engellenir. adLockOptimistic ya da 3 Kayıtseti üzerinde işlem yapıp bunu tekrar veritabanına gönderene kadar kayıtseti üzerinde herhangi bir kilit yoktur. Veritabanının yenilenme (Update) süreci içinde kayıtseti kilitlenir. adLockBatchOptimistic ya da 4 Değişiklikler toplu yapılır. kayıtseti dediğimiz nedir? Resme bakarsanız daha iyi anlayacaksınız. Okunan kayıtların üstünde gezinen o ok'a recordset denir...  strSql isimli bir değişken tanımladık ve bu değişkene veritabanı içindeki tablomuza bağlantıyı sağlayacak ifadeyi atadık. Kod:
dim strSql strSql = "SELECT * FROM tblUye" Kod:
objRs.Open strSql, objConn, , , &H0001 objRs = Kayıtseti (Nesnesi) EOF (End Of File) = Dosyanın, kuyruğun sonu.. Kayıtsetinin sonunu gösterir. Türkçesi kayıtseti boş ise... demek. Accesste en son kayıt herzaman boştur. Hiç bir veri okunmadıysa kayıtseti bu satırdadır ve değeri false'dir. Tam türkçe ile veritabanı içindeki tblUye Boş ise demektir. Kod:
if objRs.EOF then Kod:
<tr> <td>Veritabanı boş</td> </tr> üst tarafta if objRs.EOF then ile veritabanı boş ise demiştik else ile burada boş değilse demek istedik yani tabloya herhangi bir veri yazılmış ise bu koddan sonrası icra edilir... Kod:
else while = ...ıncaya kadar... Not = ... Değilse(olumsuzluk) ... objRs = Kayıtseti (Nesnesi) EOF (End Of File) = Dosyanın, kuyruğun sonu.. Tam türkçesi en son veriye kadar bu ilemi tekrar tekrar yap demektir. Kod:
do while Not objRs.EOF tblUye isimli tablo içindeki alanlara verdiğimiz isimleri buradan çağırıyor ve içindekileri sayfaya aktarıyoruz. <% = %> bu Response.Write demektir. Kod:
<tr>
<td><% = objRs("UYE_ID") %></td>
<td><% = objRs("UYE_AD") %></td>
<td><% = objRs("UYE_SOYAD") %></td>
<td><% = objRs("UYE_MAIL") %></td>
<td><% = objRs("UYE_SEHIR") %></td>
<td><% = objRs("UYE_MESAJ") %></td>
</tr>
veiratanındaki ilk kayıt okunur. Kod buraya gelince aşağıdaki komut ile, hemen üstteki kısma do while Not objRs.EOF döner ve bu işi son verinin okunmasına ve kayıtsetinin boş satıra gelmesine kadar döner durur ve <tr> ile </tr> arasını her dönüşte bir alttaki satır içinde bulunan değerler ile doldurarak dönmeye devam eder. Kod:
objRs.MoveNext() loop Kod:
end if Kayıtseti nesnesini kapatıyor ve değerlerini boşaltıyoruz. Bunu yapmazsak kodumuz onlarca kullanıcı ile çalıştığında hem sayfanın geç açılmasına hemde sunucuyu boşa meşgul ederek sunucuyu yormaya ve performansını düşürmemize sebep oluruz. Kod:
objRs.Close set objRs = Nothing Bağlantı nesnesini de kapatıyor ve değerlerini boşaltıyoruz. Kod:
objConn.Close set objConn = Nothing  Mesajınızda: -> Mail Adresinizi verirseniz, -> Konuyla alakasız yorum yaparsanız / Konuyla alakasız bir soru sorarsanız, -> Amaçsız, içinde paylaşım olmayan, saçma konular açarsanız, -> Üstüste mesaj yazarsanız ( Flood yapmakda denir), -> Küfür ederseniz, -> Konuyla alakasız bir başlık atarsanız, -> Mesajınızın tamamını büyük harfler veya puntolar kullanarak yazarsanız, Mesajınız SİLİNİR ayrıca siz BANLANIRSINIZ.  Bu tip mesajları ihbar etmek için yukarıda işaretlenmiş olan yere tıklayarak yöneticiyi uyarabilirsiniz. нαуαт, öℓüмℓє кυмαя σуηαмα ѕαηαтı∂ıя... [ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] AkdenizForum Toolbar Sitemizi Daha İyi Kullanmak İstiyorsanız Daha Kolaylıkla Sizde İndirin [ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] |
|
|
|
01-20-2008
|
#2 |
|
Se®ve® Administ®ato®
|
Veritabanına (Access) Yeni Kayıt Girmek.
Konu : Veritabanına (Access) Yeni Kayıt Girmek.
Seviye : Basit Kaynak Dosyalar :[ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] wwwroot içine DERS isimli Klasöre koyun ve unutmayın DERS klasörüne yazma izni verin. Yazma izni nasıl veririm? DERS klasörüne sağ tıklayın ve özelliklerden Web Paylaşımı sekmesine geçin. Bu klasörü Paylaşın radio düğmesini işaretleyiniz bir sihirbaz açılacak oradaki yazma vb. seçenekleri seçip uygulayın... İlk önce bir form sayfasına ihtiyacımız var. kayit_form.html Kod:
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>Kayıt Formu</title>
<**** **********="Content-Type" content="text/html; charset=iso-8859-9">
</head>
<body>
<table align="center" border="0" cellpadding="0" cellspacing="0" width="300">
<form action="kayit_kaydet.asp" method="post">
<tr>
<td>Ad :</td>
<td><input type="text" name="txtAd" size="20" maxlength="15" value=""></td>
</tr>
<tr>
<td>Soyad :</td>
<td><input type="text" name="txtSoyad" size="20" maxlength="25" value=""></td>
</tr>
<tr>
<td>Mail :</td>
<td><input type="text" name="txtMail" size="20" maxlength="30" value=""></td>
</tr>
<tr>
<td>Şehir :</td>
<td>
<select name="txtSehir">
<option value="Adana">Adana</option>
<option value="Adıyaman">Adıyaman</option>
<option value="Afyon">Afyon</option>
<option value="Ağrı">Ağrı</option>
<option value="Amasya">Amasya</option>
<option value="Ankara">Ankara</option>
</select>
</td>
</tr>
<tr>
<td>Mesaj :</td>
<td><textarea rows="5" cols="30" name="txtMesaj"></textarea></td>
</tr>
<tr>
<td> </td>
<td><input type="submit" value="Kaydet"></td>
</tr>
</form>
</table>
</body>
</html>
formdan gelen bilgileri veritabanına kaydedecek asp sayfamız. kayit_kaydet.asp Kod:
<%
'Adovbs.inc dosyası içindeki sabitlerimiz. Kayıt işlemi yaparken lazım olacak....
const adCmdText = &H0001
const adExecuteNoRecords = &H00000080
'Form içindeki name="txtAd" isimli form elemanımızdan içine yazılmış olan ismi alıyor ve bu değeri strAd değişkenine atıyoruz(yüklüyoruz).
dim strAd
strAd = Request.Form("txtAd")
'Form içindeki name="txtSoyad" isimli form elemanımızdan içine yazılmış olan soyismi alıyor ve bu değeri strSoyad değişkenine atıyoruz(yüklüyoruz).
dim strSoyad
strSoyad = Request.Form("txtSoyad")
'Form içindeki name="txtMail" isimli form elemanımızdan içine yazılmış olan Mail adresini alıyor ve bu değeri strMail değişkenine atıyoruz(yüklüyoruz).
dim strMail
strMail = Request.Form("txtMail")
'Form içindeki name="txtSehir" isimli form elemanımızdan içine yazılmış olan Sehir ismini alıyor ve bu değeri strSehir değişkenine atıyoruz(yüklüyoruz).
dim strSehir
strSehir = Request.Form("txtSehir")
'Form içindeki name="txtMesaj" isimli form elemanımızdan içine yazılmış olan Mesajı alıyor ve bu değeri strMesaj değişkenine atıyoruz(yüklüyoruz).
dim strMesaj
strMesaj = Request.Form("txtMesaj")
'Veritabanına Bağlanıyoruz.
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
'Bağlantıyı açıyoruz.
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
strSql = "INSERT INTO tblUye(UYE_AD, UYE_SOYAD, UYE_MAIL, UYE_SEHIR, UYE_MESAJ) VALUES('" & strAd & "', '" & strSoyad & "', '" & strMail & "', '" & strSehir & "', '" & strMesaj & "')"
objConn.Execute(strSql),,adCmdText + adExecuteNoRecords
'Bağlantıyı kapatıyoruz.
objConn.Close
set objConn = Nothing
'Yazdığımız kaydı gösteren sayfaya "kayit_oku.asp" yönlendiriyoruz..
Response.Redirect "kayit_oku.asp"
%>
konuyu açıklayıcı resimler aşağıda...   |
|
|
|
|
01-20-2008
|
#3 |
|
Se®ve® Administ®ato®
|
Veritabanından Bilgileri Silmek
Konu : Veritabanından Bilgileri Silmek
Seviye : Basit Kaynak Dosyalar :[ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] Veritabanından verileri silebilmek için öncelikle silme işlemi yapacağımız verileri sayfaya dökmemiz lazım ki istediklerimizi seçip silebilelim. Veritabanından kayıtları sayfaya dökme konusunu bir üst konuda açıklamıştım onu küçük bir Kod:
<a href="sil.asp?id=<% = objRs("UYE_ID") %>">Sil</a>
 kayit_oku.asp (veritabanındaki silme işlemini uygulayacağımız kayıtların tümünü burada sergiliyoruz.) Kod:
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>Veritabanından kayıt okumak</title>
<**** **********="Content-Type" content="text/html; charset=iso-8859-9">
</head>
<body>
<table border="1" cellpadding="0" cellspacing="0" width="100%">
<%
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
'strConn = "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
dim objRs
set objRs = Server.CreateObject("ADODB.Recordset")
objRs.CursorType = 0
objRs.CursorLocation = 2
objRs.LockType = 1
dim strSql
strSql = "SELECT * FROM tblUye"
objRs.Open strSql, objConn, , , &H0001
if objRs.EOF then
%>
<tr>
<td>Veritabanı boş</td>
</tr>
<%
else
dim intSayac
intSayac = 0
dim strRenk
do while Not objRs.EOF
if intSayac mod 2 then
strRenk = "#e8e8e8"
else
strRenk = "#ffffcc"
end if
%>
<tr bgcolor="<% = strRenk %>">
<td><% = objRs("UYE_ID") %></td>
<td><% = objRs("UYE_AD") %></td>
<td><% = objRs("UYE_SOYAD") %></td>
<td><% = objRs("UYE_MAIL") %></td>
<td><% = objRs("UYE_SEHIR") %></td>
<td><% = objRs("UYE_MESAJ") %></td>
<td><a href="sil.asp?id=<% = objRs("UYE_ID") %>">Sil</a></td>
</tr>
<%
intSayac = intSayac + 1
objRs.MoveNext
loop
end if
objRs.Close
set objRs = Nothing
objConn.Close
set objConn = Nothing
%>
</table>
</body>
</html>
sil.asp (silme işlemini yapacak sayfamız) Kod:
<%
'Veritabanından silinecek olan verinin id numarasını alıyoruz. Bu gelen id numarasına sahip satırı sileceğiz.
dim intID
intID = Request.QueryString("id")
'---- CommandTypeEnum Values ----
const adCmdText = &H0001
'---- ExecuteOptionEnum Values ----
Const adExecuteNoRecords = &H00000080
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
dim strSql
strSql = "DELETE FROM tblUye WHERE UYE_ID = " & intID
objConn.Execute(strSql),,adCmdText + adExecuteNoRecords
objConn.Close
set objConn = Nothing
Response.Redirect "kayit_oku.asp"
%>
|
|
|
|
|
01-20-2008
|
#4 |
|
Se®ve® Administ®ato®
|
Veritabanından Bilgileri Güncellemek
Konu : Veritabanından Bilgileri Güncellemek
Seviye : Basit Kaynak Dosyalar :[ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] Öncelikle şema olarak anlatıyorum altta kodları vereceğim. Kodları zaman zaman açıklayacağım.  Güncellenecek bilgileri listeleyeğimiz sayfamız. kayit_oku.asp Kod:
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>Veritabanından kayıt okumak</title>
<**** **********="Content-Type" content="text/html; charset=iso-8859-9">
</head>
<body>
<table border="1" cellpadding="0" cellspacing="0" width="100%">
<%
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
dim objRs
set objRs = Server.CreateObject("ADODB.Recordset")
objRs.CursorType = 0
objRs.CursorLocation = 2
objRs.LockType = 1
dim strSql
strSql = "SELECT * FROM tblUye"
objRs.Open strSql, objConn, , , &H0001
if objRs.EOF then
%>
<tr>
<td>Veritabanı boş</td>
</tr>
<%
else
dim intSayac
intSayac = 0
dim strRenk
do while Not objRs.EOF
if intSayac mod 2 then
strRenk = "#e8e8e8"
else
strRenk = "#ffffcc"
end if
%>
<tr bgcolor="<% = strRenk %>">
<td><% = objRs("UYE_AD") %></td>
<td><% = objRs("UYE_SOYAD") %></td>
<td><a href="guncelle.asp?id=<% = objRs("UYE_ID") %>">Güncelle</a></td>
</tr>
<%
intSayac = intSayac + 1
objRs.MoveNext
loop
end if
objRs.Close
set objRs = Nothing
objConn.Close
set objConn = Nothing
%>
</table>
</body>
</html>
Güncellenecek veri bilgilerinin form elemanları içerisine alınıp değişiklik yapacağımız sayfa. guncelle.asp Kod:
<% @ Language=VBScript CodePage="1254" %>
<%
Option explicit
Response.Buffer = true
%>
<%
dim intUyeID
if Request.QueryString("id") <> "" then
intUyeID = Request.QueryString("id")
else
Response.Redirect("kayit_oku.asp")
end if
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title></title>
<style type="text/css">
<!--
body {
margin:0px;
padding:0px;
}
-->
</style>
<**** **********="Content-Type" content="text/html; charset=iso-8859-9">
</head>
<body>
<table border="0" cellpadding="0" cellspacing="0" width="100%">
<tr>
<td align="center">
<%
dim objRs
set objRs = Server.CreateObject("ADODB.Recordset")
objRs.CursorLocation = 3
objRs.CursorType = 0
objRs.LockType = 3
dim strSql
strSql = "SELECT * FROM tblUye WHERE UYE_ID = " & intUyeID & ""
objRs.Open strSql, objConn, , , &H0001
if not objRs.EOF then
dim strAd
strAd = objRs("UYE_AD")
dim strSoyad
strSoyad = objRs("UYE_SOYAD")
dim strMail
strMail = objRs("UYE_MAIL")
dim strSehir
strSehir = objRs("UYE_SEHIR")
dim strMesaj
strMesaj = objRs("UYE_MESAJ")
%>
<table border="0" cellpadding="0" cellspacing="0" width="779">
<form action="guncelle_islem.asp" method="POST">
<input type="hidden" name="id" value="<% = intUyeID %>">
<tr>
<td width="120">Ad :</td>
<td><input type="text" name="ad" value="<% = strAd %>" size="20"></td>
</tr>
<tr>
<td width="120">Soyad :</td>
<td><input type="text" name="soyad" value="<% = strSoyad %>" size="20"></td>
</tr>
<tr>
<td width="120">Mail :</td>
<td><input type="text" name="mail" value="<% = strMail %>" size="20"></td>
</tr>
<tr>
<td width="120">Şehir :</td>
<td>
<select name="sehir">
<%
dim arrIller
arrIller = Array("Seçiniz","Adana","Adıyaman","Afyon","Ağrı","Aksaray","Amasya","Ankara","Antalya","Ardahan","Artvin","Aydın","Balıkesir","Bartın","Batman","Bayburt","Bilecik","Bingöl","Bitlis","Bolu","Burdur","Bursa","Çanakkale","Çankırı","Çorum","Denizli","Diyarbakır","Düzce","Edirne","Elazığ","Erzincan","Erzurum","Eskişehir","Gaziantep","Giresun","Gümüşhane","Hakkari","Hatay","Iğdır","Isparta","İstanbul","İzmir","K.Maraş","Karabük","Karaman","Kars","Kastamonu","Kayseri","Kırıkkale","Kırklareli","Kırşehir","Kilis","Kocaeli","Konya","Kütahya","Malatya","Manisa","Mardin","Mersin","Muğla","Muş","Nevsehir","Niğde","Ordu","Osmaniye","Rize","Sakarya","Samsun","Siirt","Sinop","Sivas","Şanlıurfa","Şırnak","Tekirdağ","Tokat","Trabzon","Tunceli","Uşak","Van","Yalova","Yozgat","Zonguldak")
dim strSelected
dim intSayac
for intSayac = 0 to UBound(arrIller)
if arrIller(intSayac) <> "" then
if arrIller(intSayac) = strSehir then strSelected=" selected" else strSelected=""
end if
Response.Write " <option value=""" & arrIller(intSayac) & """" & strSelected & ">" & arrIller(intSayac) & "</option>" & vbNewLine
next
%>
</select>
</td>
</tr>
<tr>
<td width="120" valign="top">Mesaj :</td>
<td><textarea rows="5" cols="35" name="mesaj" class="input"><% = strMesaj %></textarea></td>
</tr>
<tr>
<td width="120"> </td>
<td><input type="submit" value="Güncelle"></td>
</tr>
</form>
</table>
<%
end if
objRs.Close
Set objRs = Nothing
%>
</td>
</tr>
</table>
</body>
</html>
<%
objConn.Close
Set objConn = Nothing
%>
Değiştirilen bilgileri formdan alıp veritabanına kaydedecek olan sayfamız. guncelle_islem.asp Kod:
<%
intUyeID = Request.Form("id")
strAd = Request.Form("ad")
strSoyad = Request.Form("soyad")
strMail = Request.Form("mail")
strSehir = Request.Form("sehir")
strMesaj = Request.Form("mesaj")
const adCmdText = &H0001
const adExecuteNoRecords = &H00000080
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
strSql = "UPDATE tblUye SET UYE_AD = '" & strAd & "', UYE_SOYAD = '" & strSoyad & "', UYE_MAIL = '" & strMail & "', UYE_SEHIR = '" & strSehir & "', UYE_MESAJ = '" & strMesaj & "' WHERE UYE_ID = " & intUyeID
objConn.Execute(strSql),,adCmdText + adExecuteNoRecords
objConn.Close
Set objConn = Nothing
Response.Redirect "kayit_oku.asp"
%>
|
|
|
|
|
01-20-2008
|
#5 |
|
Se®ve® Administ®ato®
|
Sayfalama İşlemi
Konu : Sayfalama İşlemi
Seviye : Orta Kaynak Dosyalar : [ÜYE OLMADAN LİNKLERİ GÖREMEZSİNİZ. BURAYA TIKLAYARAK BEDAVA ÜYE OLUN...] Kod:
<% @ Language = VBScript CodePage = 1254 %>
<%
'/////////////////////////////////////////////////////////////////
Option Explicit
Response.Buffer = True
Response.Expires = -1
'/////////////////////////////////////////////////////////////////
'---- CursorTypeEnum Values ----
Const adOpenStatic = 3
'---- LockTypeEnum Values ----
Const adLockReadOnly = 1
'---- CommandTypeEnum Values ----
Const adCmdText = &H0001
'/////////////////////////////////////////////////////////////////
Dim intHerSayfadaGosterilecekKayit
intHerSayfadaGosterilecekKayit = 20
'intHerSayfadaGosterilecekKayit (Her sayfada göstereceğiniz kayıt sayısı ile değiştirebilirsiniz.)
Dim intSayfa
if Request.QueryString("s") = "" then
intSayfa = 1
else
intSayfa = CInt(Request.QueryString("s"))
end if
'intSayfa (Açık olan sayfa sayısını alırız. Sayfa "s" değişkeninin değeri yok ise 1 değeri atanır. Bu değer boş değil ise sayfadan gönderilen sayı alınır.)
'/////////////////////////////////////////////////////////////////
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>ornek</title>
<**** **********="Content-Type" content="text/html; charset=iso-8859-9">
<style type="text/css">
<!--
body {
margin:0px;
padding:0px;
}
.sayfa {
font-family: Verdana, Arial, Helvetica, sans-serif;
font-size: 12px;
font-weight:bold;
color: #ffcc00;
}
A.link_01:link {
font-family: Verdana, Arial, Helvetica, sans-serif;
font-size: 12px;
font-weight:bold;
color: #0077b5;
text-decoration: none
}
A.link_01:visited {
font-family: Verdana, Arial, Helvetica, sans-serif;
font-size: 12px;
font-weight:bold;
color: #0077b5;
text-decoration: none
}
A.link_01:active {
font-family: Verdana, Arial, Helvetica, sans-serif;
font-size: 12px;
font-weight:bold;
color: #0077b5;
text-decoration: none
}
A.link_01:hover {
font-family: Verdana, Arial, Helvetica, sans-serif;
font-size: 12px;
font-weight:bold;
color: #ffcc00;
text-decoration: none
}
-->
</style>
</head>
<body>
<table align="center" border="0" cellpadding="0" cellspacing="0" width="100%">
<tr>
<td>
<table border="0" cellpadding="0" cellspacing="0" width="779">
<tr>
<td colspan="2" height="80"> </td>
</tr>
<tr>
<td width="179"> </td>
<td width="600">
<table border="1" cellpadding="0" cellspacing="0" width="100%">
<%
dim strConn
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("veritabani.mdb")
dim objConn
set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConn
dim objRs
set objRs = Server.CreateObject("ADODB.Recordset")
dim strSql
strSql = "SELECT * FROM tblVeri"
objRs.PageSize = intHerSayfadaGosterilecekKayit '(Bir sayfada görüntülenecek kayıt sayısını belirtir.)
objRs.CacheSize = intHerSayfadaGosterilecekKayit
objRs.Open strSql, objConn, adOpenStatic, adLockReadOnly, adCmdText
dim intToplamSayfa
intToplamSayfa = objRs.PageCount
if intSayfa > intToplamSayfa then intSayfa = intToplamSayfa
if intSayfa < 1 then intSayfa = 1
if objRs.EOF then
'if intToplamSayfa = 0 then
%>
<tr>
<td align="center" valign="middle" height="200" class="sayfa">Kayıt yok</td>
</tr>
<%
else
objRs.AbsolutePage = intSayfa '(kayıtsetine hangi sayfada olduğunu bildirir.)
%>
<tr>
<td align="center" class="sayfa">Toplam <%= intToplamSayfa %> sayfa bulunmakta ve siz <%= intSayfa %>. sayfadasınız.</td>
</tr>
<%
dim intSayac01
intSayac01 = 0
do while intSayac01 < intHerSayfadaGosterilecekKayit And Not objRs.EOF
%>
<tr>
<td><% = objRs("veri") %></td>
</tr>
<%
intSayac01 = intSayac01 + 1
objRs.MoveNext
loop
%>
<tr>
<td align="center">
<%
if intSayfa > 1 then
%>
<B><a href="sayfalama.asp?s=<%= intSayfa - 1 %>" class="link_01">[<< Geri]</a> </B>
<%
end if
dim intSayac02
for intSayac02 = 1 To intToplamSayfa
if intSayac02 = intSayfa then
%>
<font class="sayfa"><%= intSayac02 %></font>
<%
else
%>
<B><a href="sayfalama.asp?s=<%= intSayac02 %>" class="link_01"><%= intSayac02 %></a></B>
<%
end if
next
if intSayfa < intToplamSayfa then
%>
<B> <a href="sayfalama.asp?s=<%= intSayfa + 1 %>" class="link_01">[ileri >>]</a></B>
<%
end if
%>
</td>
</tr>
<%
end if
objRs.Close
set objRs = Nothing
objConn.Close
set objConn = Nothing
%>
</table>
</td>
</tr>
<tr>
<td colspan="2" height="20"> </td>
</tr>
</table>
</td>
</tr>
</table>
</body>
</html>
|
|
|
|
